86e2789960
* update github.com/PuerkitoBio/goquery * update github.com/alecthomas/chroma * update github.com/blevesearch/bleve/v2 * update github.com/caddyserver/certmagic * update github.com/go-enry/go-enry/v2 * update github.com/go-git/go-billy/v5 * update github.com/go-git/go-git/v5 * update github.com/go-redis/redis/v8 * update github.com/go-testfixtures/testfixtures/v3 * update github.com/jaytaylor/html2text * update github.com/json-iterator/go * update github.com/klauspost/compress * update github.com/markbates/goth * update github.com/mattn/go-isatty * update github.com/mholt/archiver/v3 * update github.com/microcosm-cc/bluemonday * update github.com/minio/minio-go/v7 * update github.com/prometheus/client_golang * update github.com/unrolled/render * update github.com/xanzy/go-gitlab * update github.com/yuin/goldmark * update github.com/yuin/goldmark-highlighting Co-authored-by: techknowlogick <techknowlogick@gitea.io>
72 lines
1.9 KiB
ArmAsm
Vendored
72 lines
1.9 KiB
ArmAsm
Vendored
// Copyright (c) 2015 Klaus Post, released under MIT License. See LICENSE file.
|
|
|
|
//+build amd64,!gccgo,!noasm,!appengine
|
|
|
|
// func asmCpuid(op uint32) (eax, ebx, ecx, edx uint32)
|
|
TEXT ·asmCpuid(SB), 7, $0
|
|
XORQ CX, CX
|
|
MOVL op+0(FP), AX
|
|
CPUID
|
|
MOVL AX, eax+8(FP)
|
|
MOVL BX, ebx+12(FP)
|
|
MOVL CX, ecx+16(FP)
|
|
MOVL DX, edx+20(FP)
|
|
RET
|
|
|
|
// func asmCpuidex(op, op2 uint32) (eax, ebx, ecx, edx uint32)
|
|
TEXT ·asmCpuidex(SB), 7, $0
|
|
MOVL op+0(FP), AX
|
|
MOVL op2+4(FP), CX
|
|
CPUID
|
|
MOVL AX, eax+8(FP)
|
|
MOVL BX, ebx+12(FP)
|
|
MOVL CX, ecx+16(FP)
|
|
MOVL DX, edx+20(FP)
|
|
RET
|
|
|
|
// func asmXgetbv(index uint32) (eax, edx uint32)
|
|
TEXT ·asmXgetbv(SB), 7, $0
|
|
MOVL index+0(FP), CX
|
|
BYTE $0x0f; BYTE $0x01; BYTE $0xd0 // XGETBV
|
|
MOVL AX, eax+8(FP)
|
|
MOVL DX, edx+12(FP)
|
|
RET
|
|
|
|
// func asmRdtscpAsm() (eax, ebx, ecx, edx uint32)
|
|
TEXT ·asmRdtscpAsm(SB), 7, $0
|
|
BYTE $0x0F; BYTE $0x01; BYTE $0xF9 // RDTSCP
|
|
MOVL AX, eax+0(FP)
|
|
MOVL BX, ebx+4(FP)
|
|
MOVL CX, ecx+8(FP)
|
|
MOVL DX, edx+12(FP)
|
|
RET
|
|
|
|
// From https://go-review.googlesource.com/c/sys/+/285572/
|
|
// func asmDarwinHasAVX512() bool
|
|
TEXT ·asmDarwinHasAVX512(SB), 7, $0-1
|
|
MOVB $0, ret+0(FP) // default to false
|
|
|
|
#ifdef GOOS_darwin // return if not darwin
|
|
#ifdef GOARCH_amd64 // return if not amd64
|
|
// These values from:
|
|
// https://github.com/apple/darwin-xnu/blob/xnu-4570.1.46/osfmk/i386/cpu_capabilities.h
|
|
#define commpage64_base_address 0x00007fffffe00000
|
|
#define commpage64_cpu_capabilities64 (commpage64_base_address+0x010)
|
|
#define commpage64_version (commpage64_base_address+0x01E)
|
|
#define hasAVX512F 0x0000004000000000
|
|
MOVQ $commpage64_version, BX
|
|
MOVW (BX), AX
|
|
CMPW AX, $13 // versions < 13 do not support AVX512
|
|
JL no_avx512
|
|
MOVQ $commpage64_cpu_capabilities64, BX
|
|
MOVQ (BX), AX
|
|
MOVQ $hasAVX512F, CX
|
|
ANDQ CX, AX
|
|
JZ no_avx512
|
|
MOVB $1, ret+0(FP)
|
|
|
|
no_avx512:
|
|
#endif
|
|
#endif
|
|
RET
|
|
|